home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
pc
/
LOGIC Apple II 5.25" Library - DOS Part 3
/
DOS064.dsk
/
MORTGAGE TABLE.bas
< prev
next >
Wrap
BASIC Source File
|
2012-02-16
|
2KB
|
79 lines
10 PRINT "MORTGAGE AMORTIZATION TABLE"
20 PRINT
30 PRINT "REGULAR PAYMENT";
40 INPUT R
50 PRINT "TERM IN YEARS, MONTHS";
60 INPUT Y0,M
65 Y = (12 *Y0 +M)/12
70 PRINT "PRINCIPAL";
80 INPUT P
90 PRINT "ANNUAL INTEREST RATE";
100 INPUT I
110 I = I/100
120 PRINT "NUMBER OF PAYMENTS PER YEAR";
130 INPUT N
140 PRINT "START PRINTING WITH WHAT YEAR";
150 INPUT X
155 PRINT "<CTRL-D>PR#1": PRINT "<CTRL-I>K": HOME
160 X = INT(X)
170 C1 = 0
180 I2 = 0
190 I3 = 0
200 J0 = 0
210 N1 = N
220 K = 66
230 B0 = P
240 A1 = 0
250 A2 = 0
260 IF INT(Y) <1 THEN 690
270 FOR J0 = 1 TO INT(Y)
280 IF J0 <X THEN 410
290 IF K +N +3 <58 THEN 400
300 FOR K1 = K TO 66
310 PRINT
320 NEXT K1
330 PRINT " "
340 PRINT " MORTGAGE AMORTIZATION TABLE"
350 PRINT " PRINCIPAL $";P;" AT ";I *100;"% FOR ";Y0;" YEARS ";M;" MONTHS"
360 PRINT " REGULAR PAYMENT = $";R
370 PRINT " "
380 PRINT "NO."; TAB( 10);"INTEREST"; TAB( 20);"AMORTIZED"; TAB( 30);"BALANCE"; TAB( 40);"ACCUM INTEREST"
390 K = 7
400 K = K +N +3
410 FOR J1 = 1 TO N1
420 I1 = INT((B0 *I/N) *100 +.5)/100
430 C1 = C1 +1
440 A = R -I1
450 A1 = A1 +A
460 B0 = P -A1
470 IF C1 < >N *Y THEN 520
480 R = R +B0
490 A = A +B0
500 A1 = A1 +B0
510 B0 = 0
520 I2 = I2 +I1
530 I3 = I3 +I1
540 A2 = A2 +A
550 IF J0 <X THEN 570
560 PRINT J1; TAB( 10);I1; TAB( 20);A; TAB( 30);B0; TAB( 40);I2
570 NEXT J1
580 IF C1 < >N *Y THEN 600
590 PRINT " LAST PAYMENT = $";( INT(R *100 +.5))/100
600 IF J0 <X THEN 640
610 PRINT " "
620 PRINT "YR.";J0; TAB( 10);I3; TAB( 20);A2
630 PRINT " "
640 IF J0 >Y THEN 720
650 I3 = 0
660 A2 = 0
670 NEXT J0
680 IF Y = J0 THEN 720
690 N1 = ((Y - INT(Y)) *12)/12 *N
700 J0 = J0 +1
710 GOTO 280
720 PRINT
730 PRINT "CHANGE DATA AND RECOMPUTE? (1=YES, 0=NO)";
740 INPUT Z
750 IF Z = 1 THEN 20
760 PRINT "<CTRL-D>PR#0"
770 PRINT "<CTRL-D>RUN HELLO"